You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
466 lines
14 KiB
466 lines
14 KiB
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
#.rst:
|
|
# FindOpenSSL
|
|
# -----------
|
|
#
|
|
# Find the OpenSSL encryption library.
|
|
#
|
|
# Imported Targets
|
|
# ^^^^^^^^^^^^^^^^
|
|
#
|
|
# This module defines the following :prop_tgt:`IMPORTED` targets:
|
|
#
|
|
# ``OpenSSL::SSL``
|
|
# The OpenSSL ``ssl`` library, if found.
|
|
# ``OpenSSL::Crypto``
|
|
# The OpenSSL ``crypto`` library, if found.
|
|
#
|
|
# Result Variables
|
|
# ^^^^^^^^^^^^^^^^
|
|
#
|
|
# This module will set the following variables in your project:
|
|
#
|
|
# ``OPENSSL_FOUND``
|
|
# System has the OpenSSL library.
|
|
# ``OPENSSL_INCLUDE_DIR``
|
|
# The OpenSSL include directory.
|
|
# ``OPENSSL_CRYPTO_LIBRARY``
|
|
# The OpenSSL crypto library.
|
|
# ``OPENSSL_SSL_LIBRARY``
|
|
# The OpenSSL SSL library.
|
|
# ``OPENSSL_LIBRARIES``
|
|
# All OpenSSL libraries.
|
|
# ``OPENSSL_VERSION``
|
|
# This is set to ``$major.$minor.$revision$patch`` (e.g. ``0.9.8s``).
|
|
#
|
|
# Hints
|
|
# ^^^^^
|
|
#
|
|
# Set ``OPENSSL_ROOT_DIR`` to the root directory of an OpenSSL installation.
|
|
# Set ``OPENSSL_USE_STATIC_LIBS`` to ``TRUE`` to look for static libraries.
|
|
# Set ``OPENSSL_MSVC_STATIC_RT`` set ``TRUE`` to choose the MT version of the lib.
|
|
|
|
if (UNIX)
|
|
find_package(PkgConfig QUIET)
|
|
pkg_check_modules(_OPENSSL QUIET openssl)
|
|
endif ()
|
|
|
|
# Support preference of static libs by adjusting CMAKE_FIND_LIBRARY_SUFFIXES
|
|
if(OPENSSL_USE_STATIC_LIBS)
|
|
set(_openssl_ORIG_CMAKE_FIND_LIBRARY_SUFFIXES ${CMAKE_FIND_LIBRARY_SUFFIXES})
|
|
if(WIN32)
|
|
set(CMAKE_FIND_LIBRARY_SUFFIXES .lib .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
|
|
else()
|
|
set(CMAKE_FIND_LIBRARY_SUFFIXES .a )
|
|
endif()
|
|
endif()
|
|
|
|
if (WIN32)
|
|
# http://www.slproweb.com/products/Win32OpenSSL.html
|
|
set(_OPENSSL_ROOT_HINTS
|
|
${OPENSSL_ROOT_DIR}
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\OpenSSL (32-bit)_is1;Inno Setup: App Path]"
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\OpenSSL (64-bit)_is1;Inno Setup: App Path]"
|
|
ENV OPENSSL_ROOT_DIR
|
|
)
|
|
file(TO_CMAKE_PATH "$ENV{PROGRAMFILES}" _programfiles)
|
|
set(_OPENSSL_ROOT_PATHS
|
|
"${_programfiles}/OpenSSL"
|
|
"${_programfiles}/OpenSSL-Win32"
|
|
"${_programfiles}/OpenSSL-Win64"
|
|
"C:/OpenSSL/"
|
|
"C:/OpenSSL-Win32/"
|
|
"C:/OpenSSL-Win64/"
|
|
)
|
|
unset(_programfiles)
|
|
else ()
|
|
set(_OPENSSL_ROOT_HINTS
|
|
${OPENSSL_ROOT_DIR}
|
|
ENV OPENSSL_ROOT_DIR
|
|
)
|
|
endif ()
|
|
|
|
set(_OPENSSL_ROOT_HINTS_AND_PATHS
|
|
HINTS ${_OPENSSL_ROOT_HINTS}
|
|
PATHS ${_OPENSSL_ROOT_PATHS}
|
|
)
|
|
|
|
find_path(OPENSSL_INCLUDE_DIR
|
|
NAMES
|
|
openssl/ssl.h
|
|
${_OPENSSL_ROOT_HINTS_AND_PATHS}
|
|
HINTS
|
|
${_OPENSSL_INCLUDEDIR}
|
|
PATH_SUFFIXES
|
|
include
|
|
)
|
|
|
|
if(WIN32 AND NOT CYGWIN)
|
|
if(MSVC)
|
|
# /MD and /MDd are the standard values - if someone wants to use
|
|
# others, the libnames have to change here too
|
|
# use also ssl and ssleay32 in debug as fallback for openssl < 0.9.8b
|
|
# enable OPENSSL_MSVC_STATIC_RT to get the libs build /MT (Multithreaded no-DLL)
|
|
# In Visual C++ naming convention each of these four kinds of Windows libraries has it's standard suffix:
|
|
# * MD for dynamic-release
|
|
# * MDd for dynamic-debug
|
|
# * MT for static-release
|
|
# * MTd for static-debug
|
|
|
|
# Implementation details:
|
|
# We are using the libraries located in the VC subdir instead of the parent directory even though :
|
|
# libeay32MD.lib is identical to ../libeay32.lib, and
|
|
# ssleay32MD.lib is identical to ../ssleay32.lib
|
|
# enable OPENSSL_USE_STATIC_LIBS to use the static libs located in lib/VC/static
|
|
|
|
if (OPENSSL_MSVC_STATIC_RT)
|
|
set(_OPENSSL_MSVC_RT_MODE "MT")
|
|
else ()
|
|
set(_OPENSSL_MSVC_RT_MODE "MD")
|
|
endif ()
|
|
|
|
# Since OpenSSL 1.1, lib names are like libcrypto32MTd.lib and libssl32MTd.lib
|
|
if( "${CMAKE_SIZEOF_VOID_P}" STREQUAL "8" )
|
|
set(_OPENSSL_MSVC_ARCH_SUFFIX "64")
|
|
else()
|
|
set(_OPENSSL_MSVC_ARCH_SUFFIX "32")
|
|
endif()
|
|
|
|
if(OPENSSL_USE_STATIC_LIBS)
|
|
set(_OPENSSL_PATH_SUFFIXES
|
|
"lib/VC/static"
|
|
"VC/static"
|
|
"lib"
|
|
)
|
|
else()
|
|
set(_OPENSSL_PATH_SUFFIXES
|
|
"lib/VC"
|
|
"VC"
|
|
"lib"
|
|
)
|
|
endif ()
|
|
|
|
find_library(LIB_EAY_DEBUG
|
|
NAMES
|
|
libcrypto${_OPENSSL_MSVC_ARCH_SUFFIX}${_OPENSSL_MSVC_RT_MODE}d
|
|
libcrypto${_OPENSSL_MSVC_RT_MODE}d
|
|
libcryptod
|
|
libeay32${_OPENSSL_MSVC_RT_MODE}d
|
|
libeay32d
|
|
cryptod
|
|
NAMES_PER_DIR
|
|
${_OPENSSL_ROOT_HINTS_AND_PATHS}
|
|
PATH_SUFFIXES
|
|
${_OPENSSL_PATH_SUFFIXES}
|
|
)
|
|
|
|
find_library(LIB_EAY_RELEASE
|
|
NAMES
|
|
libcrypto${_OPENSSL_MSVC_ARCH_SUFFIX}${_OPENSSL_MSVC_RT_MODE}
|
|
libcrypto${_OPENSSL_MSVC_RT_MODE}
|
|
libcrypto
|
|
libeay32${_OPENSSL_MSVC_RT_MODE}
|
|
libeay32
|
|
crypto
|
|
NAMES_PER_DIR
|
|
${_OPENSSL_ROOT_HINTS_AND_PATHS}
|
|
PATH_SUFFIXES
|
|
${_OPENSSL_PATH_SUFFIXES}
|
|
)
|
|
|
|
find_library(SSL_EAY_DEBUG
|
|
NAMES
|
|
libssl${_OPENSSL_MSVC_ARCH_SUFFIX}${_OPENSSL_MSVC_RT_MODE}d
|
|
libssl${_OPENSSL_MSVC_RT_MODE}d
|
|
libssld
|
|
ssleay32${_OPENSSL_MSVC_RT_MODE}d
|
|
ssleay32d
|
|
ssld
|
|
NAMES_PER_DIR
|
|
${_OPENSSL_ROOT_HINTS_AND_PATHS}
|
|
PATH_SUFFIXES
|
|
${_OPENSSL_PATH_SUFFIXES}
|
|
)
|
|
|
|
find_library(SSL_EAY_RELEASE
|
|
NAMES
|
|
libssl${_OPENSSL_MSVC_ARCH_SUFFIX}${_OPENSSL_MSVC_RT_MODE}
|
|
libssl${_OPENSSL_MSVC_RT_MODE}
|
|
libssl
|
|
ssleay32${_OPENSSL_MSVC_RT_MODE}
|
|
ssleay32
|
|
ssl
|
|
NAMES_PER_DIR
|
|
${_OPENSSL_ROOT_HINTS_AND_PATHS}
|
|
PATH_SUFFIXES
|
|
${_OPENSSL_PATH_SUFFIXES}
|
|
)
|
|
|
|
set(LIB_EAY_LIBRARY_DEBUG "${LIB_EAY_DEBUG}")
|
|
set(LIB_EAY_LIBRARY_RELEASE "${LIB_EAY_RELEASE}")
|
|
set(SSL_EAY_LIBRARY_DEBUG "${SSL_EAY_DEBUG}")
|
|
set(SSL_EAY_LIBRARY_RELEASE "${SSL_EAY_RELEASE}")
|
|
|
|
include(${CMAKE_CURRENT_LIST_DIR}/SelectLibraryConfigurations.cmake)
|
|
select_library_configurations(LIB_EAY)
|
|
select_library_configurations(SSL_EAY)
|
|
|
|
mark_as_advanced(LIB_EAY_LIBRARY_DEBUG LIB_EAY_LIBRARY_RELEASE
|
|
SSL_EAY_LIBRARY_DEBUG SSL_EAY_LIBRARY_RELEASE)
|
|
set(OPENSSL_SSL_LIBRARY ${SSL_EAY_LIBRARY} )
|
|
set(OPENSSL_CRYPTO_LIBRARY ${LIB_EAY_LIBRARY} )
|
|
elseif(MINGW)
|
|
# same player, for MinGW
|
|
set(LIB_EAY_NAMES crypto libeay32)
|
|
set(SSL_EAY_NAMES ssl ssleay32)
|
|
find_library(LIB_EAY
|
|
NAMES
|
|
${LIB_EAY_NAMES}
|
|
NAMES_PER_DIR
|
|
${_OPENSSL_ROOT_HINTS_AND_PATHS}
|
|
PATH_SUFFIXES
|
|
"lib/MinGW"
|
|
"lib"
|
|
)
|
|
|
|
find_library(SSL_EAY
|
|
NAMES
|
|
${SSL_EAY_NAMES}
|
|
NAMES_PER_DIR
|
|
${_OPENSSL_ROOT_HINTS_AND_PATHS}
|
|
PATH_SUFFIXES
|
|
"lib/MinGW"
|
|
"lib"
|
|
)
|
|
|
|
mark_as_advanced(SSL_EAY LIB_EAY)
|
|
set(OPENSSL_SSL_LIBRARY ${SSL_EAY} )
|
|
set(OPENSSL_CRYPTO_LIBRARY ${LIB_EAY} )
|
|
unset(LIB_EAY_NAMES)
|
|
unset(SSL_EAY_NAMES)
|
|
else()
|
|
# Not sure what to pick for -say- intel, let's use the toplevel ones and hope someone report issues:
|
|
find_library(LIB_EAY
|
|
NAMES
|
|
libcrypto
|
|
libeay32
|
|
NAMES_PER_DIR
|
|
${_OPENSSL_ROOT_HINTS_AND_PATHS}
|
|
HINTS
|
|
${_OPENSSL_LIBDIR}
|
|
PATH_SUFFIXES
|
|
lib
|
|
)
|
|
|
|
find_library(SSL_EAY
|
|
NAMES
|
|
libssl
|
|
ssleay32
|
|
NAMES_PER_DIR
|
|
${_OPENSSL_ROOT_HINTS_AND_PATHS}
|
|
HINTS
|
|
${_OPENSSL_LIBDIR}
|
|
PATH_SUFFIXES
|
|
lib
|
|
)
|
|
|
|
mark_as_advanced(SSL_EAY LIB_EAY)
|
|
set(OPENSSL_SSL_LIBRARY ${SSL_EAY} )
|
|
set(OPENSSL_CRYPTO_LIBRARY ${LIB_EAY} )
|
|
endif()
|
|
else()
|
|
|
|
find_library(OPENSSL_SSL_LIBRARY
|
|
NAMES
|
|
ssl
|
|
ssleay32
|
|
ssleay32MD
|
|
NAMES_PER_DIR
|
|
${_OPENSSL_ROOT_HINTS_AND_PATHS}
|
|
HINTS
|
|
${_OPENSSL_LIBDIR}
|
|
PATH_SUFFIXES
|
|
lib
|
|
)
|
|
|
|
find_library(OPENSSL_CRYPTO_LIBRARY
|
|
NAMES
|
|
crypto
|
|
NAMES_PER_DIR
|
|
${_OPENSSL_ROOT_HINTS_AND_PATHS}
|
|
HINTS
|
|
${_OPENSSL_LIBDIR}
|
|
PATH_SUFFIXES
|
|
lib
|
|
)
|
|
|
|
mark_as_advanced(OPENSSL_CRYPTO_LIBRARY OPENSSL_SSL_LIBRARY)
|
|
|
|
# compat defines
|
|
set(OPENSSL_SSL_LIBRARIES ${OPENSSL_SSL_LIBRARY})
|
|
set(OPENSSL_CRYPTO_LIBRARIES ${OPENSSL_CRYPTO_LIBRARY})
|
|
|
|
endif()
|
|
|
|
function(from_hex HEX DEC)
|
|
string(TOUPPER "${HEX}" HEX)
|
|
set(_res 0)
|
|
string(LENGTH "${HEX}" _strlen)
|
|
|
|
while (_strlen GREATER 0)
|
|
math(EXPR _res "${_res} * 16")
|
|
string(SUBSTRING "${HEX}" 0 1 NIBBLE)
|
|
string(SUBSTRING "${HEX}" 1 -1 HEX)
|
|
if (NIBBLE STREQUAL "A")
|
|
math(EXPR _res "${_res} + 10")
|
|
elseif (NIBBLE STREQUAL "B")
|
|
math(EXPR _res "${_res} + 11")
|
|
elseif (NIBBLE STREQUAL "C")
|
|
math(EXPR _res "${_res} + 12")
|
|
elseif (NIBBLE STREQUAL "D")
|
|
math(EXPR _res "${_res} + 13")
|
|
elseif (NIBBLE STREQUAL "E")
|
|
math(EXPR _res "${_res} + 14")
|
|
elseif (NIBBLE STREQUAL "F")
|
|
math(EXPR _res "${_res} + 15")
|
|
else()
|
|
math(EXPR _res "${_res} + ${NIBBLE}")
|
|
endif()
|
|
|
|
string(LENGTH "${HEX}" _strlen)
|
|
endwhile()
|
|
|
|
set(${DEC} ${_res} PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
if(OPENSSL_INCLUDE_DIR AND EXISTS "${OPENSSL_INCLUDE_DIR}/openssl/opensslv.h")
|
|
file(STRINGS "${OPENSSL_INCLUDE_DIR}/openssl/opensslv.h" openssl_version_str
|
|
REGEX "^#[\t ]*define[\t ]+OPENSSL_VERSION_NUMBER[\t ]+0x([0-9a-fA-F])+.*")
|
|
|
|
if(openssl_version_str)
|
|
# The version number is encoded as 0xMNNFFPPS: major minor fix patch status
|
|
# The status gives if this is a developer or prerelease and is ignored here.
|
|
# Major, minor, and fix directly translate into the version numbers shown in
|
|
# the string. The patch field translates to the single character suffix that
|
|
# indicates the bug fix state, which 00 -> nothing, 01 -> a, 02 -> b and so
|
|
# on.
|
|
|
|
string(REGEX REPLACE "^.*OPENSSL_VERSION_NUMBER[\t ]+0x([0-9a-fA-F])([0-9a-fA-F][0-9a-fA-F])([0-9a-fA-F][0-9a-fA-F])([0-9a-fA-F][0-9a-fA-F])([0-9a-fA-F]).*$"
|
|
"\\1;\\2;\\3;\\4;\\5" OPENSSL_VERSION_LIST "${openssl_version_str}")
|
|
list(GET OPENSSL_VERSION_LIST 0 OPENSSL_VERSION_MAJOR)
|
|
list(GET OPENSSL_VERSION_LIST 1 OPENSSL_VERSION_MINOR)
|
|
from_hex("${OPENSSL_VERSION_MINOR}" OPENSSL_VERSION_MINOR)
|
|
list(GET OPENSSL_VERSION_LIST 2 OPENSSL_VERSION_FIX)
|
|
from_hex("${OPENSSL_VERSION_FIX}" OPENSSL_VERSION_FIX)
|
|
list(GET OPENSSL_VERSION_LIST 3 OPENSSL_VERSION_PATCH)
|
|
|
|
if (NOT OPENSSL_VERSION_PATCH STREQUAL "00")
|
|
from_hex("${OPENSSL_VERSION_PATCH}" _tmp)
|
|
# 96 is the ASCII code of 'a' minus 1
|
|
math(EXPR OPENSSL_VERSION_PATCH_ASCII "${_tmp} + 96")
|
|
unset(_tmp)
|
|
# Once anyone knows how OpenSSL would call the patch versions beyond 'z'
|
|
# this should be updated to handle that, too. This has not happened yet
|
|
# so it is simply ignored here for now.
|
|
string(ASCII "${OPENSSL_VERSION_PATCH_ASCII}" OPENSSL_VERSION_PATCH_STRING)
|
|
endif ()
|
|
|
|
set(OPENSSL_VERSION "${OPENSSL_VERSION_MAJOR}.${OPENSSL_VERSION_MINOR}.${OPENSSL_VERSION_FIX}${OPENSSL_VERSION_PATCH_STRING}")
|
|
endif ()
|
|
endif ()
|
|
|
|
include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
|
|
|
|
set(OPENSSL_LIBRARIES ${OPENSSL_SSL_LIBRARY} ${OPENSSL_CRYPTO_LIBRARY} )
|
|
|
|
if (OPENSSL_VERSION)
|
|
find_package_handle_standard_args(OpenSSL
|
|
REQUIRED_VARS
|
|
#OPENSSL_SSL_LIBRARY # FIXME: require based on a component request?
|
|
OPENSSL_CRYPTO_LIBRARY
|
|
OPENSSL_INCLUDE_DIR
|
|
VERSION_VAR
|
|
OPENSSL_VERSION
|
|
FAIL_MESSAGE
|
|
"Could NOT find OpenSSL, try to set the path to OpenSSL root folder in the system variable OPENSSL_ROOT_DIR"
|
|
)
|
|
else ()
|
|
find_package_handle_standard_args(OpenSSL "Could NOT find OpenSSL, try to set the path to OpenSSL root folder in the system variable OPENSSL_ROOT_DIR"
|
|
#OPENSSL_SSL_LIBRARY # FIXME: require based on a component request?
|
|
OPENSSL_CRYPTO_LIBRARY
|
|
OPENSSL_INCLUDE_DIR
|
|
)
|
|
endif ()
|
|
|
|
mark_as_advanced(OPENSSL_INCLUDE_DIR OPENSSL_LIBRARIES)
|
|
|
|
if(OPENSSL_FOUND)
|
|
if(NOT TARGET OpenSSL::Crypto AND
|
|
(EXISTS "${OPENSSL_CRYPTO_LIBRARY}" OR
|
|
EXISTS "${LIB_EAY_LIBRARY_DEBUG}" OR
|
|
EXISTS "${LIB_EAY_LIBRARY_RELEASE}")
|
|
)
|
|
add_library(OpenSSL::Crypto UNKNOWN IMPORTED)
|
|
set_target_properties(OpenSSL::Crypto PROPERTIES
|
|
INTERFACE_INCLUDE_DIRECTORIES "${OPENSSL_INCLUDE_DIR}")
|
|
if(EXISTS "${OPENSSL_CRYPTO_LIBRARY}")
|
|
set_target_properties(OpenSSL::Crypto PROPERTIES
|
|
IMPORTED_LINK_INTERFACE_LANGUAGES "C"
|
|
IMPORTED_LOCATION "${OPENSSL_CRYPTO_LIBRARY}")
|
|
endif()
|
|
if(EXISTS "${LIB_EAY_LIBRARY_RELEASE}")
|
|
set_property(TARGET OpenSSL::Crypto APPEND PROPERTY
|
|
IMPORTED_CONFIGURATIONS RELEASE)
|
|
set_target_properties(OpenSSL::Crypto PROPERTIES
|
|
IMPORTED_LINK_INTERFACE_LANGUAGES_RELEASE "C"
|
|
IMPORTED_LOCATION_RELEASE "${LIB_EAY_LIBRARY_RELEASE}")
|
|
endif()
|
|
if(EXISTS "${LIB_EAY_LIBRARY_DEBUG}")
|
|
set_property(TARGET OpenSSL::Crypto APPEND PROPERTY
|
|
IMPORTED_CONFIGURATIONS DEBUG)
|
|
set_target_properties(OpenSSL::Crypto PROPERTIES
|
|
IMPORTED_LINK_INTERFACE_LANGUAGES_DEBUG "C"
|
|
IMPORTED_LOCATION_DEBUG "${LIB_EAY_LIBRARY_DEBUG}")
|
|
endif()
|
|
endif()
|
|
if(NOT TARGET OpenSSL::SSL AND
|
|
(EXISTS "${OPENSSL_SSL_LIBRARY}" OR
|
|
EXISTS "${SSL_EAY_LIBRARY_DEBUG}" OR
|
|
EXISTS "${SSL_EAY_LIBRARY_RELEASE}")
|
|
)
|
|
add_library(OpenSSL::SSL UNKNOWN IMPORTED)
|
|
set_target_properties(OpenSSL::SSL PROPERTIES
|
|
INTERFACE_INCLUDE_DIRECTORIES "${OPENSSL_INCLUDE_DIR}")
|
|
if(EXISTS "${OPENSSL_SSL_LIBRARY}")
|
|
set_target_properties(OpenSSL::SSL PROPERTIES
|
|
IMPORTED_LINK_INTERFACE_LANGUAGES "C"
|
|
IMPORTED_LOCATION "${OPENSSL_SSL_LIBRARY}")
|
|
endif()
|
|
if(EXISTS "${SSL_EAY_LIBRARY_RELEASE}")
|
|
set_property(TARGET OpenSSL::SSL APPEND PROPERTY
|
|
IMPORTED_CONFIGURATIONS RELEASE)
|
|
set_target_properties(OpenSSL::SSL PROPERTIES
|
|
IMPORTED_LINK_INTERFACE_LANGUAGES_RELEASE "C"
|
|
IMPORTED_LOCATION_RELEASE "${SSL_EAY_LIBRARY_RELEASE}")
|
|
endif()
|
|
if(EXISTS "${SSL_EAY_LIBRARY_DEBUG}")
|
|
set_property(TARGET OpenSSL::SSL APPEND PROPERTY
|
|
IMPORTED_CONFIGURATIONS DEBUG)
|
|
set_target_properties(OpenSSL::SSL PROPERTIES
|
|
IMPORTED_LINK_INTERFACE_LANGUAGES_DEBUG "C"
|
|
IMPORTED_LOCATION_DEBUG "${SSL_EAY_LIBRARY_DEBUG}")
|
|
endif()
|
|
if(TARGET OpenSSL::Crypto)
|
|
set_target_properties(OpenSSL::SSL PROPERTIES
|
|
INTERFACE_LINK_LIBRARIES OpenSSL::Crypto)
|
|
endif()
|
|
endif()
|
|
endif()
|
|
|
|
# Restore the original find library ordering
|
|
if(OPENSSL_USE_STATIC_LIBS)
|
|
set(CMAKE_FIND_LIBRARY_SUFFIXES ${_openssl_ORIG_CMAKE_FIND_LIBRARY_SUFFIXES})
|
|
endif()
|