You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
93 lines
4.1 KiB
93 lines
4.1 KiB
set(CMAKE_DL_LIBS "dl")
|
|
set(CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG "-Wl,-rpath,")
|
|
set(CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG_SEP ":")
|
|
set(CMAKE_SHARED_LIBRARY_RPATH_ORIGIN_TOKEN "\$ORIGIN")
|
|
set(CMAKE_SHARED_LIBRARY_RPATH_LINK_C_FLAG "-Wl,-rpath-link,")
|
|
set(CMAKE_SHARED_LIBRARY_SONAME_C_FLAG "-Wl,-soname,")
|
|
set(CMAKE_EXE_EXPORTS_C_FLAG "-Wl,--export-dynamic")
|
|
|
|
# Shared libraries with no builtin soname may not be linked safely by
|
|
# specifying the file path.
|
|
set(CMAKE_PLATFORM_USES_PATH_WHEN_NO_SONAME 1)
|
|
|
|
# Initialize C link type selection flags. These flags are used when
|
|
# building a shared library, shared module, or executable that links
|
|
# to other libraries to select whether to use the static or shared
|
|
# versions of the libraries.
|
|
foreach(type SHARED_LIBRARY SHARED_MODULE EXE)
|
|
set(CMAKE_${type}_LINK_STATIC_C_FLAGS "-Wl,-Bstatic")
|
|
set(CMAKE_${type}_LINK_DYNAMIC_C_FLAGS "-Wl,-Bdynamic")
|
|
endforeach()
|
|
|
|
|
|
# Features for LINK_LIBRARY generator expression
|
|
## check linker capabilities
|
|
if(NOT DEFINED _CMAKE_LINKER_PUSHPOP_STATE_SUPPORTED)
|
|
execute_process(COMMAND "${CMAKE_LINKER}" --help
|
|
OUTPUT_VARIABLE __linker_help
|
|
ERROR_VARIABLE __linker_help)
|
|
if(__linker_help MATCHES "--push-state" AND __linker_help MATCHES "--pop-state")
|
|
set(_CMAKE_LINKER_PUSHPOP_STATE_SUPPORTED TRUE CACHE INTERNAL "linker supports push/pop state")
|
|
else()
|
|
set(_CMAKE_LINKER_PUSHPOP_STATE_SUPPORTED FALSE CACHE INTERNAL "linker supports push/pop state")
|
|
endif()
|
|
unset(__linker_help)
|
|
endif()
|
|
## WHOLE_ARCHIVE: Force loading all members of an archive
|
|
if(_CMAKE_LINKER_PUSHPOP_STATE_SUPPORTED)
|
|
set(CMAKE_LINK_LIBRARY_USING_WHOLE_ARCHIVE "LINKER:--push-state,--whole-archive"
|
|
"<LINK_ITEM>"
|
|
"LINKER:--pop-state")
|
|
else()
|
|
set(CMAKE_LINK_LIBRARY_USING_WHOLE_ARCHIVE "LINKER:--whole-archive"
|
|
"<LINK_ITEM>"
|
|
"LINKER:--no-whole-archive")
|
|
endif()
|
|
set(CMAKE_LINK_LIBRARY_USING_WHOLE_ARCHIVE_SUPPORTED TRUE)
|
|
|
|
# Features for LINK_GROUP generator expression
|
|
## RESCAN: request the linker to rescan static libraries until there is
|
|
## no pending undefined symbols
|
|
set(CMAKE_LINK_GROUP_USING_RESCAN "LINKER:--start-group" "LINKER:--end-group")
|
|
set(CMAKE_LINK_GROUP_USING_RESCAN_SUPPORTED TRUE)
|
|
|
|
|
|
# Debian policy requires that shared libraries be installed without
|
|
# executable permission. Fedora policy requires that shared libraries
|
|
# be installed with the executable permission. Since the native tools
|
|
# create shared libraries with execute permission in the first place a
|
|
# reasonable policy seems to be to install with execute permission by
|
|
# default. In order to support debian packages we provide an option
|
|
# here. The option default is based on the current distribution, but
|
|
# packagers can set it explicitly on the command line.
|
|
if(DEFINED CMAKE_INSTALL_SO_NO_EXE)
|
|
# Store the decision variable in the cache. This preserves any
|
|
# setting the user provides on the command line.
|
|
set(CMAKE_INSTALL_SO_NO_EXE "${CMAKE_INSTALL_SO_NO_EXE}" CACHE INTERNAL
|
|
"Install .so files without execute permission.")
|
|
else()
|
|
# Store the decision variable as an internal cache entry to avoid
|
|
# checking the platform every time. This option is advanced enough
|
|
# that only package maintainers should need to adjust it. They are
|
|
# capable of providing a setting on the command line.
|
|
if(EXISTS "/etc/debian_version")
|
|
set(CMAKE_INSTALL_SO_NO_EXE 1 CACHE INTERNAL
|
|
"Install .so files without execute permission.")
|
|
else()
|
|
set(CMAKE_INSTALL_SO_NO_EXE 0 CACHE INTERNAL
|
|
"Install .so files without execute permission.")
|
|
endif()
|
|
endif()
|
|
|
|
# Match multiarch library directory names.
|
|
set(CMAKE_LIBRARY_ARCHITECTURE_REGEX "[a-z0-9_]+(-[a-z0-9_]+)?-linux-gnu[a-z0-9_]*")
|
|
|
|
include(Platform/UnixPaths)
|
|
|
|
# Debian has lib32 and lib64 paths only for compatibility so they should not be
|
|
# searched.
|
|
if(NOT CMAKE_CROSSCOMPILING AND EXISTS "/etc/debian_version")
|
|
set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB32_PATHS FALSE)
|
|
set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS FALSE)
|
|
endif()
|